1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
|
/* Copyright (C) 2003 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <sysdep.h>
#include <lowlevelrwlock.h>
#include <tcb-offsets.h>
#include <pthread-errnos.h>
#include "lowlevel-atomic.h"
#define SYS_gettimeofday __NR_gettimeofday
#define SYS_futex 240
#define FUTEX_WAIT 0
#define FUTEX_WAKE 1
.text
.globl pthread_rwlock_timedrdlock
.type pthread_rwlock_timedrdlock,@function
.align 5
pthread_rwlock_timedrdlock:
mov.l r12, @-r15
mov.l r9, @-r15
mov.l r8, @-r15
sts.l pr, @-r15
add #-8, r15
mov r4, r8
mov r5, r9
/* Get the lock. */
mov #1, r3
#if MUTEX == 0
XADD (r3, @r4, r2)
#else
XADD (r3, @(MUTEX,r4), r2)
#endif
tst r2, r2
bf 1f
2:
mov.l @(WRITER,r8), r0
tst r0, r0
bf 14f
mov.l @(WRITERS_QUEUED,r8), r0
tst r0, r0
bt 5f
mov.l @(FLAGS,r8), r0
tst r0, r0
bt 5f
3:
/* Check the value of the timeout parameter. */
mov.l .L1g0, r1
mov.l @(4,r9), r0
cmp/hs r1, r0
bt 19f
mov.l @(READERS_QUEUED,r8), r0
add #1, r0
mov.l r0, @(READERS_QUEUED,r8)
tst r0, r0
bt 4f
#if MUTEX == 0
DEC (@r8, r2)
#else
DEC (@(MUTEX,r8), r2)
#endif
tst r2, r2
bf 10f
11:
/* Get current time. */
mov r15, r4
mov #0, r5
mov #SYS_gettimeofday, r3
trapa #0x12
SYSCALL_INST_PAD
mov.l @(4,r15), r0
mov.w .L1k0, r1
dmulu.l r0, r1 /* Milli seconds to nano seconds. */
mov.l @r9, r2
mov.l @(4,r9), r3
mov.l @r15, r0
sts macl, r1
sub r0, r2
clrt
subc r1, r3
bf 15f
mov.l .L1g0, r1
add r1, r3
add #-1, r2
15:
cmp/pz r2
bf 16f /* Time is already up. */
/* Store relative timeout. */
mov.l r2, @r15
mov.l r3, @(4,r15)
/* Futex call. */
mov r15, r7
mov #FUTEX_WAIT, r5
mov.l @(READERS_WAKEUP,r8), r6
mov r8, r4
add #READERS_WAKEUP, r4
mov #SYS_futex, r3
extu.b r3, r3
trapa #0x14
SYSCALL_INST_PAD
mov r0, r3
17:
/* Reget the lock. */
mov r8, r4
mov #1, r5
#if MUTEX == 0
XADD (r5, @r4, r2)
#else
XADD (r5, @(MUTEX,r4), r2)
#endif
tst r2, r2
bf 12f
13:
mov.l @(READERS_QUEUED,r8), r0
add #-1, r0
mov.l r0, @(READERS_QUEUED,r8)
mov #-ETIMEDOUT, r0
cmp/eq r0, r3
bf 2b
18:
bra 9f
mov #ETIMEDOUT, r3
5:
mov #0, r3
mov.l @(NR_READERS,r8), r0
add #1, r0
mov.l r0, @(NR_READERS,r8)
tst r0, r0
bt 8f
9:
#if MUTEX == 0
DEC (@r8, r2)
#else
DEC (@(MUTEX,r8), r2)
#endif
tst r2, r2
bf 6f
7:
add #8,r15
lds.l @r15+, pr
mov.l @r15+, r8
mov.l @r15+, r9
mov.l @r15+, r12
rts
mov r3, r0
.align 2
.L1k0:
.long 1000
.L1g0:
.long 1000000000
1:
mov r8, r5
#if MUTEX != 0
add #MUTEX, r5
#endif
mov r2, r4
mov.l .Lwait2, r1
bsrf r1
nop
.Lwait2b:
bra 2b
nop
14:
stc gbr, r1
mov.w .Ltcboff,r2
sub r2,r1
cmp/eq r1, r0
bf 3b
/* Deadlock detected. */
bra 9b
mov #EDEADLK, r3
6:
mov r8, r4
#if MUTEX != 0
add #MUTEX, r4
#endif
mov.l .Lwake2, r1
bsrf r1
nop
.Lwake2b:
bra 7b
mov #0, r3
8:
/* Overflow. */
mov.l @(NR_READERS,r8), r1
add #-1, r1
mov.l r1, @(NR_READERS,r8)
bra 9b
mov #EAGAIN, r3
4:
/* Overflow. */
mov.l @(READERS_QUEUED,r8), r1
add #-1, r1
mov.l r1, @(READERS_QUEUED,r8)
bra 9b
mov #EAGAIN, r3
10:
mov r8, r4
#if MUTEX != 0
add #MUTEX, r4
#endif
mov.l .Lwake3, r1
bsrf r1
nop
.Lwake3b:
bra 11b
nop
12:
mov r8, r5
#if MUTEX != 0
add #MUTEX, r5
#endif
mov r2, r4
mov.l .Lwait3, r1
bsrf r1
nop
.Lwait3b:
bra 13b
nop
16:
bra 17b
mov #-ETIMEDOUT, r3
19:
bra 9b
mov #EINVAL, r3
.Ltcboff:
.word TLS_PRE_TCB_SIZE
.align 2
.Lwait2:
.long __lll_mutex_lock_wait-.Lwait2b
.Lwake2:
.long __lll_mutex_unlock_wake-.Lwake2b
.Lwait3:
.long __lll_mutex_lock_wait-.Lwait3b
.Lwake3:
.long __lll_mutex_unlock_wake-.Lwake3b
.size pthread_rwlock_timedrdlock,.-pthread_rwlock_timedrdlock
|