1 files changed, 102 insertions, 0 deletions
diff --git a/sysdeps/unix/sysv/linux/alpha/gettimeofday.S b/sysdeps/unix/sysv/linux/alpha/gettimeofday.S
new file mode 100644
index 0000000000..bceeefc0a7
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/alpha/gettimeofday.S
@@ -0,0 +1,102 @@
+/* Copyright (C) 1998 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Library General Public License as
+   published by the Free Software Foundation; either version 2 of the
+   License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Library General Public License for more details.
+
+   You should have received a copy of the GNU Library General Public
+   License along with the GNU C Library; see the file COPYING.LIB.  If not,
+   write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
+   Boston, MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+#define _ERRNO_H        1
+#include <bits/errno.h>
+
+/* The problem here is that initially we made struct timeval compatible with
+   OSF/1, using int32.  But we defined time_t with uint64, and later found
+   that POSIX requires tv_sec to be time_t.
+
+   So now we have to do compatibility stuff.  */
+
+/* The variable is shared between all wrappers around signal handling
+   functions which have RT equivalents.  */
+.comm __libc_missing_axp_tv64, 4
+
+.text
+
+LEAF(__gettimeofday_tv64, 16)
+	ldgp	gp, 0(pv)
+	subq	sp, 16, sp
+#ifdef PROF
+	.set noat
+	lda	AT, _mcount
+	jsr	AT, (AT), _mcount
+	.set at
+#endif
+	.prologue 1
+
+	ldl	t0, __libc_missing_axp_tv64
+
+	/* Save arguments in case we do need to fall back.  */
+	stq	a0, 0(sp)
+	stq	a1, 8(sp)
+
+	bne	t0, $do32
+
+	ldi	v0, SYS_ify(gettimeofday)
+	callsys
+	bne	a3, $err64
+
+	/* Everything ok.  */
+	addq	sp, 16, sp
+	ret
+
+	/* If we didn't get ENOSYS, it is a real error.  */
+	.align 3
+$err64:	cmpeq	v0, ENOSYS, t0
+	bne	t0, $error
+	stl	t0, __libc_missing_axp_tv64
+
+	/* Recover the saved arguments.  */
+	ldq	a1, 8(sp)
+	ldq	a0, 0(sp)
+
+	.align 3
+$do32:	ldi	v0, SYS_ify(osf_gettimeofday)
+	callsys
+	bne	a3, $error
+
+	/* Copy back to proper format.  */
+	ldq	a0, 0(sp)
+	beq	a0, 2f
+	ldl	t0, 0(a0)
+	ldl	t1, 4(a0)
+	stq	t0, 0(a0)
+	stq	t1, 0(a0)
+
+2:	addq	sp, 16, sp
+	ret
+
+	.align 3
+$error:
+	lda	pv, __syscall_error
+	addq	sp, 16, sp
+	jmp	zero, (pv), __syscall_error
+
+END(__gettimeofday_tv64)
+
+default_symbol_version (__gettimeofday_tv64, __gettimeofday, GLIBC_2.1)
+
+/* It seems to me to be a misfeature of the assembler that we can only
+   have one version-alias per symbol.  So create an alias ourselves.
+   The 'p' is for 'public'.  *Shrug*  */
+strong_alias (__gettimeofday_tv64, __gettimeofday_tv64p)
+default_symbol_version (__gettimeofday_tv64p, gettimeofday, GLIBC_2.1)