* Versions.def (glibc): Add GLIBC_2.9.

	* io/Makefile (routines): Add dup3 and pipe2.
	* io/Versions [glibc] (GLIBC_2.9): Add dup3 and pipe2.
	* io/dup3.c: New file.
	* io/pipe2.c: New file.
	* posix/unistd.h: Declare dup3 and pipe2.
	* socket/Makefile (routines): Add paccept.
	* socket/Versions [glibc] (GLIBC_2.9): Add paccept.
	* socket/paccept.c: New file.
	* socket/sys/socket.h: Declare paccept.
	* sysdeps/unix/syscalls.list: Add entry for dup3.
	* sysdeps/unix/sysv/linux/Versions [glibc] (GLIBC_2.9): Add
	epoll_create2 and inotify_init1.
	* sysdeps/unix/sysv/linux/eventfd.c: Use eventfd1 syscall if possible.
	* sysdeps/unix/sysv/linux/paccept.c: New file.
	* sysdeps/unix/sysv/linux/signalfd.c: Use signalfd4 syscall if
	possible.
	* sysdeps/unix/sysv/linux/socketcall.h: Add SOCKOP_paccept.
	* sysdeps/unix/sysv/linux/syscalls.list: Add epoll_create2,
	inotify_init1, and pipe2 entries.
	* sysdeps/unix/sysv/linux/alpha/sys/epoll.h: New file.
	* sysdeps/unix/sysv/linux/alpha/sys/eventfd.h: New file.
	* sysdeps/unix/sysv/linux/alpha/sys/inotify.h: New file.
	* sysdeps/unix/sysv/linux/alpha/sys/signalfd.h: New file.
	* sysdeps/unix/sysv/linux/alpha/sys/timerfd.h: New file.
	* sysdeps/unix/sysv/linux/bits/socket.h: Define SOCK_CLOEXEC and
	SOCK_NONBLOCK.
	* sysdeps/unix/sysv/linux/i386/paccept.S: New file.
	* sysdeps/unix/sysv/linux/sparc/sys/epoll.h: New file.
	* sysdeps/unix/sysv/linux/sparc/sys/eventfd.h: New file.
	* sysdeps/unix/sysv/linux/sparc/sys/inotify.h: New file.
	* sysdeps/unix/sysv/linux/sparc/sys/signalfd.h: New file.
	* sysdeps/unix/sysv/linux/sparc/sys/timerfd.h: New file.
	* sysdeps/unix/sysv/linux/sparc/bits/socket.h: New file.
	* sysdeps/unix/sysv/linux/sys/epoll.h: Define EPOLL_CLOEXEC and
	EPOLL_NONBLOCK.  Declare epoll_create2.
	* sysdeps/unix/sysv/linux/sys/eventfd.h: Define EFD_CLOEXEC and
	EFD_NONBLOCK.
	* sysdeps/unix/sysv/linux/sys/inotify.h: Define IN_CLOEXEC and
	IN_NONBLOCK.  Declare inotify_init1.
	* sysdeps/unix/sysv/linux/sys/signalfd.h: Define SFD_CLOEXEC and
	SFD_NONBLOCK.
	* sysdeps/unix/sysv/linux/sys/timerfd.h: Define TFD_CLOEXEC and
	TFD_NONBLOCK.

1 files changed, 135 insertions, 0 deletions

diff --git a/sysdeps/unix/sysv/linux/i386/paccept.S b/sysdeps/unix/sysv/linux/i386/paccept.S
new file mode 100644
index 0000000000..02ad78dd47
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/i386/paccept.S
@@ -0,0 +1,135 @@
+/* Copyright (C) 1995-1998,2002,2003,2005,2008 Free Software Foundation, Inc.
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, write to the Free
+   Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
+   02111-1307 USA.  */
+
+#include <sysdep-cancel.h>
+#include <socketcall.h>
+#include <tls.h>
+
+#define _NSIG 64
+
+#define P(a, b) P2(a, b)
+#define P2(a, b) a##b
+
+	.text
+/* The socket-oriented system calls are handled unusally in Linux.
+   They are all gated through the single `socketcall' system call number.
+   `socketcall' takes two arguments: the first is the subcode, specifying
+   which socket function is being called; and the second is a pointer to
+   the arguments to the specific function.  */
+
+ENTRY(do_paccept)
+#ifdef SOCKOP_paccept
+	subl $6*4, %esp
+	cfi_adjust_cfa_offset(6*4)
+
+	movl (%eax), %ecx
+	movl %ecx, (%esp)
+	movl 4(%eax), %ecx
+	movl %ecx, 4(%esp)
+	movl 8(%eax), %ecx
+	movl %ecx, 8(%esp)
+	movl 12(%eax), %ecx
+	movl %ecx, 12(%esp)
+	movl $(_NSIG / 8), 16(%esp)
+	movl 16(%eax), %ecx
+	movl %ecx, 20(%esp)
+
+	movl $SYS_ify(socketcall), %eax	/* System call number in %eax.  */
+
+	movl $SOCKOP_paccept, %ebx	/* Subcode is first arg to syscall.  */
+	movl %esp, %ecx			/* Address of args is 2nd arg.  */
+
+        /* Do the system call trap.  */
+	ENTER_KERNEL
+
+	addl $6*4, %esp
+	cfi_adjust_cfa_offset(-6*4)
+
+	/* %eax is < 0 if there was an error.  */
+	cmpl $-125, %eax
+	jae SYSCALL_ERROR_LABEL
+#else
+	movl $-ENOSYS, %eax
+	jmp SYSCALL_ERROR_LABEL
+
+	.section .gnu.glibc-stub.paccept
+	.previous
+	.section .gnu.warning.paccept
+	.string "warning: paccept is not implemented and will always fail"
+	.previous
+#endif
+L(pseudo_end):
+	ret
+PSEUDO_END(do_paccept)
+
+
+	.globl paccept
+ENTRY (paccept)
+#ifdef CENABLE
+	SINGLE_THREAD_P
+	jne 1f
+#endif
+
+	/* Save registers.  */
+	movl %ebx, %edx
+	cfi_register (3, 2)
+
+	lea 4(%esp), %eax
+	call do_paccept
+
+	/* Restore registers.  */
+	movl %edx, %ebx
+	cfi_restore (3)
+
+	ret
+
+#ifdef CENABLE
+	/* We need one more register.  */
+1:	pushl %esi
+	cfi_adjust_cfa_offset(4)
+
+	/* Enable asynchronous cancellation.  */
+	CENABLE
+	movl %eax, %esi
+	cfi_offset(6, -8)		/* %esi */
+
+	/* Save registers.  */
+	movl %ebx, %edx
+	cfi_register (3, 2)
+
+	lea 8(%esp), %eax
+	call do_paccept
+
+	/* Restore registers.  */
+	movl %edx, %ebx
+	cfi_restore (3)
+
+	/* Restore the cancellation.  */
+	xchgl %esi, %eax
+	CDISABLE
+
+	/* Restore registers.  */
+	movl %esi, %eax
+	popl %esi
+	cfi_restore (6)
+	cfi_adjust_cfa_offset(-4)
+
+	/* Successful; return the syscall's value.  */
+	ret
+#endif
+PSEUDO_END (paccept)