S390: Unify 31/64bit memset.

The implementation of memset for s390-32 (31bit) and
s390-64 (64bit) is nearly the same.
This patch unifies it for maintability reasons.

__memset_z10 and __memset_z196 differs between 31 and 64bit:
-31bit needs .machinemode "zarch_nohighgprs" and llgfr   %r4,%r4
-lr vs lgr and some other instructions:
But lgr and co can be also used on 31bit as this ifunc variant
is only called if we are on a zarch machine.

__memset_default differs between 31 and 64bit:
-Some 31bit vs 64bit instructions (e.g. ltr vs ltgr.
Solved with 31/64 specific instruction macros).
-The address of mvc instruction is setup in different ways
(larl vs bras). Solved with #if defined __s390x__.

Otherwise 31/64bit implementation has the same structure of the code.

ChangeLog:

	* sysdeps/s390/s390-64/memset.S: Move to ...
	* sysdeps/s390/memset.S: ... here.
	Adjust to be usable for 31/64bit.
	* sysdeps/s390/s390-32/memset.S: Delete File.
	* sysdeps/s390/multiarch/Makefile (sysdep_routines): Add memset.
	* sysdeps/s390/s390-32/multiarch/Makefile (sysdep_routines):
	Remove memset.
	* sysdeps/s390/s390-64/multiarch/Makefile: Likewise.
	* sysdeps/s390/s390-64/multiarch/memset-s390x.S: Move to ...
	* sysdeps/s390/multiarch/memset-s390x.S: ... here.
	Adjust to be usable for 31/64bit.
	* sysdeps/s390/s390-32/multiarch/memset-s390.S: Delete File.
	* sysdeps/s390/s390-64/multiarch/memset.c: Move to ...
	* sysdeps/s390/multiarch/memset.c: ... here.
	* sysdeps/s390/s390-32/multiarch/memset.c: Delete File.

1 files changed, 97 insertions, 0 deletions

diff --git a/sysdeps/s390/memset.S b/sysdeps/s390/memset.S
new file mode 100644
index 0000000000..72e7c5a42e
--- /dev/null
+++ b/sysdeps/s390/memset.S
@@ -0,0 +1,97 @@
+/* Set a block of memory to some byte value.  31/64 bit S/390 version.
+   Copyright (C) 2001-2018 Free Software Foundation, Inc.
+   Contributed by Martin Schwidefsky (schwidefsky@de.ibm.com).
+   This file is part of the GNU C Library.
+
+   The GNU C Library is free software; you can redistribute it and/or
+   modify it under the terms of the GNU Lesser General Public
+   License as published by the Free Software Foundation; either
+   version 2.1 of the License, or (at your option) any later version.
+
+   The GNU C Library is distributed in the hope that it will be useful,
+   but WITHOUT ANY WARRANTY; without even the implied warranty of
+   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+   Lesser General Public License for more details.
+
+   You should have received a copy of the GNU Lesser General Public
+   License along with the GNU C Library; if not, see
+   <http://www.gnu.org/licenses/>.  */
+
+
+#include <sysdep.h>
+#include "asm-syntax.h"
+
+/* INPUT PARAMETERS
+     %r2 = address of memory area
+     %r3 = byte to fill memory with
+     %r4 = number of bytes to fill.  */
+
+       .text
+
+#if defined __s390x__
+# define LTGR	ltgr
+# define CGHI	cghi
+# define LGR	lgr
+# define AGHI	aghi
+# define BRCTG	brctg
+#else
+# define LTGR	ltr
+# define CGHI	chi
+# define LGR	lr
+# define AGHI	ahi
+# define BRCTG	brct
+#endif /* ! defined __s390x__  */
+
+#ifdef USE_MULTIARCH
+ENTRY(__memset_default)
+#else
+ENTRY(memset)
+#endif
+#if defined __s390x__
+	.machine "z900"
+#else
+	.machine "g5"
+#endif /* ! defined __s390x__  */
+	LTGR    %r4,%r4
+	je      .L_Z900_G5_4
+	stc     %r3,0(%r2)
+	CGHI    %r4,1
+	LGR     %r1,%r2
+	je      .L_Z900_G5_4
+	AGHI    %r4,-2
+#if defined __s390x__
+	larl    %r5,.L_Z900_G5_18
+	srlg    %r3,%r4,8
+# define Z900_G5_EX_D 0
+#else
+	basr    %r5,0
+.L_Z900_G5_19:
+# define Z900_G5_EX_D .L_Z900_G5_18-.L_Z900_G5_19
+	lr      %r3,%r4
+	srl     %r3,8
+#endif /* ! defined __s390x__  */
+	LTGR    %r3,%r3
+	jne     .L_Z900_G5_14
+.L_Z900_G5_3:
+	ex      %r4,Z900_G5_EX_D(%r5)
+.L_Z900_G5_4:
+	br      %r14
+.L_Z900_G5_14:
+	mvc     1(256,%r1),0(%r1)
+	la      %r1,256(%r1)
+	BRCTG   %r3,.L_Z900_G5_14
+	j       .L_Z900_G5_3
+.L_Z900_G5_18:
+	mvc     1(1,%r1),0(%r1)
+#ifdef USE_MULTIARCH
+END(__memset_default)
+#else
+END(memset)
+libc_hidden_builtin_def (memset)
+#endif
+
+#undef LTGR
+#undef CGHI
+#undef LGR
+#undef AGHI
+#undef BRCTG