apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-android-extensions'
apply plugin: 'kotlin-kapt'
apply plugin: 'com.google.android.gms.oss-licenses-plugin'

def privateProperties = new Properties()
def conf = project.file("private.properties")
if (conf.exists()) privateProperties.load(conf.newDataInputStream())

if (privateProperties['fabric.key'] != null || System.getenv("FABRIC_KEY") != null) {
    apply plugin: 'io.fabric'
}

android {
    compileSdkVersion 28
    defaultConfig {
        applicationId "moe.yuuta.workmode"
        minSdkVersion 28
        targetSdkVersion 28
        versionCode rootProject.ext.versionCode
        versionName rootProject.ext.versionName
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"

        // Fabric
        def fabricKey = privateProperties['fabric.key']
        if (fabricKey == null) fabricKey = System.getenv("FABRIC_KEY")
        if (fabricKey == null) fabricKey = "disabled"
        buildConfigField "String", "FABRIC_KEY", "\"" + fabricKey + "\""
        manifestPlaceholders.fabricKey = fabricKey

        // Google Play Licensing
        def googlePlayLicensingKey = privateProperties['google.play.licensing.key']
        if (googlePlayLicensingKey == null) googlePlayLicensingKey = System.getenv("GOOGLE_PLAY_LICENSING_KEY")
        if (googlePlayLicensingKey == null) googlePlayLicensingKey = "disabled"
        buildConfigField "String", "GOOGLE_PLAY_LICENSING_KEY", "\"" + googlePlayLicensingKey + "\""
    }
    signingConfigs {
        general {
            def locate = privateProperties['key.locate']
            def keystorePwd = privateProperties['key.store.pwd']
            def alias = privateProperties['key.alias']
            def pwd = privateProperties['key.pwd']
            storeFile file(locate != null ? locate : project.rootProject.file(".yuuta.jks"))
            storePassword keystorePwd != null ?
                    keystorePwd : System.getenv("KEYSTORE_PASS")
            keyAlias alias != null ?
                    alias : System.getenv("ALIAS_NAME")
            keyPassword pwd != null ?
                    pwd : System.getenv("ALIAS_PASS")
            v2SigningEnabled true
        }
    }
    buildTypes {
        debug {
            signingConfig signingConfigs.general
        }
        release {
            signingConfig signingConfigs.general
            minifyEnabled true
            proguardFiles 'proguard-android-optimize.txt', 'proguard-rules.pro'
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    lintOptions {
        checkReleaseBuilds false
        abortOnError false
    }
    kapt {
        generateStubs = true
    }
    sourceSets {
        main {
            java.srcDirs += 'src/main/kotlin'
        }
    }
}

dependencies {
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation"org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
    implementation 'androidx.appcompat:appcompat:1.0.2'
    implementation 'androidx.core:core-ktx:1.0.1'
    implementation 'androidx.constraintlayout:constraintlayout:1.1.3'
    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'androidx.test.ext:junit:1.1.0'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.1.1'
    implementation 'eu.chainfire:librootjava:1.2.0'
    implementation 'com.elvishew:xlog:1.6.1'
    implementation 'eu.chainfire:libsuperuser:1.0.0.201811281328'
    implementation 'com.google.android.material:material:1.1.0-alpha03'
    implementation 'androidx.recyclerview:recyclerview:1.0.0'
    implementation 'com.google.android.gms:play-services-oss-licenses:16.0.2'
    implementation 'com.crashlytics.sdk.android:crashlytics:2.9.8'
    def lifecycle_version = "2.0.0"
    implementation "androidx.lifecycle:lifecycle-runtime:$lifecycle_version"
    implementation "androidx.lifecycle:lifecycle-common-java8:$lifecycle_version"
}